# Leavitt - Source base todo manager for C family of languages
#
# Copyright (c) 2022 Sameer Rahmani <lxsameer@gnu.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, version 2.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
cmake_minimum_required(VERSION 3.19)

# Project name and a few useful settings. Other commands can pick up the results
project(Leavitt
  VERSION 1.0.0
  DESCRIPTION "Source base todo manager for C family of languages"
  LANGUAGES CXX C)

# Clangd command file
set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
set(CMAKE_CXX_STANDARD 17 CACHE STRING "")

# Policies ==========================
cmake_policy(SET CMP0116 OLD)

# User Options ======================
option(LEAVITT_BUILD_TESTING "Enable tests" OFF)
option(LEAVITT_ENABLE_BUILDID "Enable build id." OFF)
option(LEAVITT_ENABLE_THINLTO "Enable ThisLTO." ON)
option(LEAVITT_ENABLE_DOCS "Enable document generation" OFF)
option(LEAVITT_ENABLE_TIDY "Enable clang tidy check" OFF)
option(LEAVITT_DISABLE_CCACHE "Disable automatic ccache integration" OFF)

# Only do these if this is the main project, and not if it is included through add_subdirectory
if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
  ## Settings =======================
  set(CMAKE_CXX_STANDARD_REQUIRED True)

  # Setup the source locations
  set(INCLUDE_DIR ${CMAKE_SOURCE_DIR}/include)

  if(LEAVITT_ENABLE_TIDY)
    find_program(CLANG_TIDY_PATH NAMES clang-tidy REQUIRED)
  endif()
  find_program(clang++ NAMES clang++ clang++ REQUIRED)
  find_program(lld NAMES lld lld REQUIRED)
  find_program(iwyu NAMES include-what-you-use iwyu REQUIRED)

  find_program(iwyu NAMES include-what-you-use iwyu REQUIRED)
  set(iwyu_path ${iwyu})
  # Let's ensure -std=c++xx instead of -std=g++xx
  set(CMAKE_CXX_EXTENSIONS OFF)

  set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/scripts/cmake")
  set(MemoryCheckCommand "valgrind")

  configure_file(${INCLUDE_DIR}/leavitt/config.h.in include/leavitt/config.h)

  # Let's nicely support folders in IDEs
  set_property(GLOBAL PROPERTY USE_FOLDERS ON)

  # Setup the basic compiler flags
  add_compile_options(
    -Wall
    -Wextra
    -Werror
    -fno-rtti
    -fno-builtin-strlen

    # Dedicate a section to each function, so the linker
    # can do a better job on dead code elimination
    -ffunction-sections
    -fdata-sections

    $<$<CONFIG:DEBUG>:-g3>
    $<$<CONFIG:DEBUG>:-ggdb>
    # For the sake of debugging
    $<$<CONFIG:DEBUG>:-fno-inline>
    # To make the local ccache happy
    $<$<CONFIG:DEBUG>:-fdebug-prefix-map=${PROJECT_SOURCE_DIR}=.>

    $<$<CONFIG:DEBUG>:-fno-omit-frame-pointer>
    $<$<CONFIG:RELEASE>:-fomit-frame-pointer>
    $<$<CONFIG:DEBUG>:-fsanitize=address>

    $<$<CONFIG:RELEASE>:-O3>
    $<$<CONFIG:RELEASE>:-fmerge-all-constants>
    $<$<CONFIG:RELEASE>:-flto=thin>
    )

  add_link_options(
    # We enforce the lld linker
    -fuse-ld=lld
    -Wl,-gc-sections
    $<$<CONFIG:RELEASE>:-fsanitize-address-globals-dead-stripping>
    $<$<CONFIG:DEBUG>:-fsanitize=address>
    $<$<CONFIG:RELEASE>:-flto=thin>
    $<$<CONFIG:RELEASE>:-s>
    # Do not link against shared libraries
    #--static
    )

  if (LEAVITT_USE_COMPILER_RT)
    add_link_options(-rtlib=compiler-rt -stdlib=libc++ )
  endif()

  find_program(LLD_PROGRAM REQUIRED NAMES lld)

  if(LEAVITT_ENABLE_BUILDID)
    add_link_options(-Wl,--build-id)
  endif()

  #TODO: Setup the THINLTO on release
  if(LEAVITT_ENABLE_THINLTO)
  endif()

  include(GNUInstallDirs)
  Include(FetchContent)

  # CCache support ==============================
  if(LEAVITT_DISABLE_CCACHE)
    message(STATUS "CCache support is disabled")
  else()

    find_program(CCACHE_PROGRAM ccache)

    if(CCACHE_PROGRAM)
      message(STATUS "Found CCache")
      set(LEAVITT_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
      set(LEAVITT_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
      set(LEAVITT_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
        CACHE STRING "Parameters to pass through to ccache")

      set(CCACHE_PROGRAM "${LEAVITT_CCACHE_PARAMS} ${CCACHE_PROGRAM}")

      if (LEAVITT_CCACHE_MAXSIZE)
        set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LEAVITT_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
      endif()
      if (LEAVITT_CCACHE_DIR)
        set(CCACHE_PROGRAM "CCACHE_DIR=${LEAVITT_CCACHE_DIR} ${CCACHE_PROGRAM}")
      endif()
      message(STATUS "Using CCACHE: ${CCACHE_PROGRAM}")
      set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
    else()
      message(FATAL_ERROR "Unable to find the program ccache. Set LEAVITT_DISABLE_CCACHE to ON")
    endif()
  endif()


  if(LEAVITT_BUILD_TESTING)
    message(STATUS "Fetching Googletest...")
    FetchContent_Declare(
      googletest
      URL https://github.com/google/googletest/archive/609281088cfefc76f9d0ce82e1ff6c30cc3591e5.zip
      )
    # For Windows: Prevent overriding the parent project's compiler/linker settings
    set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
    FetchContent_MakeAvailable(googletest)
  endif()

  # Clang setup =========================================

  if(DEFINED Clang_ROOT)
    set(CT_CLANG_PACKAGE_DIR "${Clang_ROOT}/../../..")
  elseif(DEFINED Clang_DIR)
    set(CT_CLANG_PACKAGE_DIR "${Clang_DIR}/../../..")
  endif()

  mark_as_advanced(CT_CLANG_PACKAGE_DIR)

  # Set this to a valid Clang installation directory. This is most likely where
  # LLVM is installed on your system.
  set(CT_Clang_INSTALL_DIR "${CT_CLANG_PACKAGE_DIR}" CACHE PATH
    "Clang installation directory")

  set(CT_LLVM_INCLUDE_DIR "${CT_Clang_INSTALL_DIR}/include/llvm")
  if(NOT EXISTS "${CT_LLVM_INCLUDE_DIR}")
    message(FATAL_ERROR
      " CT_Clang_INSTALL_DIR (${CT_LLVM_INCLUDE_DIR}) is invalid.")
  endif()

  set(CT_LLVM_CMAKE_FILE
    "${CT_Clang_INSTALL_DIR}/lib/cmake/clang/ClangConfig.cmake")
  if(NOT EXISTS "${CT_LLVM_CMAKE_FILE}")
    message(FATAL_ERROR
      " CT_LLVM_CMAKE_FILE (${CT_LLVM_CMAKE_FILE}) is invalid.")
  endif()

  list(APPEND CMAKE_PREFIX_PATH "${CT_Clang_INSTALL_DIR}/lib/cmake/clang/")

  find_package(Clang REQUIRED CONFIG)
  message(STATUS "Found Clang ${CLANG_PACKAGE_VERSION}")

  if("${LLVM_VERSION_MAJOR}" LESS "15")
    message(FATAL_ERROR "Found LLVM ${LLVM_VERSION_MAJOR}, but need LLVM 13")
  endif()

  message(STATUS "Found Clang ${LLVM_PACKAGE_VERSION}")
  message(STATUS "Using ClangConfig.cmake in: ${CT_Clang_INSTALL_DIR}")

  message("CLANG STATUS:
  Includes (clang)    ${CLANG_INCLUDE_DIRS}
  Includes (llvm)     ${LLVM_INCLUDE_DIRS}"
    )

  # Set the LLVM and Clang header and library paths
  include_directories(SYSTEM "${LLVM_INCLUDE_DIRS};${CLANG_INCLUDE_DIRS}")


  # Leavitt Setup ===================================

  include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)

  add_subdirectory(bin)

  if (LEAVITT_ENABLE_DOCS)
    add_subdirectory(docs)
  endif()

  install(DIRECTORY ${PROJECT_BINARY_DIR}/include/
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
    FILES_MATCHING
    PATTERN *.h
    PATTERN *.td
    PATTERN "CMake*" EXCLUDE)

endif()