Add install targets to install the entire serene package

CMakeLists.txt

@@ -165,6 +165,7 @@ if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
     endif()
   endif()
 
+  include(GNUInstallDirs)
 
   # LLVM setup =========================================
   find_package(LLVM REQUIRED CONFIG)
@@ -216,7 +217,7 @@ if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   list(INSERT CMAKE_MODULE_PATH 0
     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/"
     "${LLVM_COMMON_CMAKE_UTILS}/Modules"
-  )
+    )
 
   include(tablegen-serene)
   # Create the tools we use to compile Serene
@@ -232,4 +233,12 @@ if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   if (SERENE_ENABLE_DOCS)
     add_subdirectory(docs)
   endif()
+
+  install(DIRECTORY ${PROJECT_BINARY_DIR}/include/
+    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+    FILES_MATCHING
+    PATTERN *.h
+    PATTERN *.td
+    PATTERN "CMake*" EXCLUDE)
+
 endif()

libserene/CMakeLists.txt

@@ -14,11 +14,61 @@
 # You should have received a copy of the GNU General Public License
 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
 
-include_directories(${INCLUD_DIR})
+include_directories(${INCLUDE_DIR})
 
 add_subdirectory(include)
 add_subdirectory(lib)
 
+install(TARGETS serene
+  EXPORT SereneExports
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+
+
+install(DIRECTORY ${INCLUDE_DIR}/serene
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+  FILES_MATCHING
+  PATTERN *.h
+  PATTERN *.td
+  PATTERN "CMake*" EXCLUDE)
+
+
+install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+  FILES_MATCHING
+  PATTERN *.h
+  PATTERN *.td
+  PATTERN *.h.inc
+  PATTERN "CMake*" EXCLUDE)
+
+include(CMakePackageConfigHelpers)
+
+configure_package_config_file(
+  "${CMAKE_CURRENT_SOURCE_DIR}/cmake/${PROJECT_NAME}Config.cmake.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
+
+  INSTALL_DESTINATION
+  ${CMAKE_INSTALL_LIBDIR}/cmake/serene-${PROJECT_VERSION}
+  )
+
+write_basic_package_version_file(
+  "${PROJECT_NAME}ConfigVersion.cmake"
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY SameMajorVersion
+  )
+
+install(FILES
+  "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
+  "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
+  DESTINATION
+  ${CMAKE_INSTALL_LIBDIR}/cmake/serene-${PROJECT_VERSION}
+  )
+
+install(EXPORT SereneExports
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/serene-${PROJECT_VERSION}
+  NAMESPACE serene::)
+
 # Testing only available if this is the main app
 # Emergency override SERENE_CMAKE_BUILD_TESTING provided as well
 if(SERENE_BUILD_TESTING)

libserene/cmake/SereneConfig.cmake.in

@@ -0,0 +1,21 @@
+ # Serene Programming Language
+#
+# Copyright (c) 2019-2022 Sameer Rahmani <lxsameer@gnu.org>
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation, version 2.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_NAME@Exports.cmake")
+
+check_required_components("@PROJECT_NAME@")