serene/flake.nix

{
  description = "Serene programming language";

  inputs.nixpkgs.url = "/home/lxsameer/src/nixpkgs/";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs = inputs@{ self, nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        llvm = {
          url = "https://devheroes.codes/Serene/llvm-project.git";
          major = "16";
          version = "16.0.6";
          rev = "b2c0361bcc08afdf466a605a23924bcd64fa2b86";
          hash = "sha256-wUKHwWYYlKa0v5zEJXxndleYtK7wzJKi0vqr3lNkGMI=";
          rev-version = "17-disable-shared-1";
        };

        overlays = [
          (self: super:
            {
              serene_toolchain = (super.callPackage (super.path + "/pkgs/development/compilers/llvm/${llvm.major}") ({
                inherit (super.stdenvAdapters) overrideCC;
                buildLlvmTools = super.buildPackages.serene_toolchain.tools;
                targetLlvmLibraries = self.targetPackages.serene_toolchain.libraries or self.serene_toolchain.libraries;
                targetLlvm = self.targetPackages.serene_toolchain.llvm or self.serene_toolchain.llvm;
                monorepoSrc = super.fetchgit {
                  url = llvm.url;
                  rev = llvm.rev;
                  hash = llvm.hash;
                };
                officialRelease = null;
                gitRelease = {
                  version = llvm.version;
                  rev = llvm.rev;
                  rev-version = llvm.rev-version;
                };
              }));
            })
          (final: prev: {
            cpio = prev.cpio.overrideAttrs (old: {
              patches = [
                ./patches/0001-configure-Include-needed-header-for-major-minor-macr.patch
              ];
              nativeBuildInputs = [ prev.autoreconfHook ];
              NIX_CFLAGS_COMPILE = "-Wno-implicit-function-declaration";
            });

            libedit = prev.libedit.overrideAttrs (old: {
              # Musl is ISO 10646 compliant but doesn't define __STDC_ISO_10646__ we need to do it ourselves
              NIX_CFLAGS_COMPILE = "-D__STDC_ISO_10646__=201103L";
            });

            elfutils = prev.elfutils.overrideAttrs (old: {
              # libcxx does not have __cxa_demangle
              configureFlags = old.configureFlags ++ [ "--disable-demangler" ];
            });

            ccache = prev.ccache.overrideAttrs (old: {
              nativeBuildInputs = old.nativeBuildInputs ++ [ final.elfutils ];
            });

            # We don't need systemd at all
            util-linux = prev.util-linux.override { systemdSupport = false; };
          })
        ];

        get_pkgs = system:
          if system == "x86_64-linux"
            then import nixpkgs {
            inherit system overlays;
            crossSystem = nixpkgs.lib.systems.examples.musl64 // { useLLVM = true; };
            config.replaceCrossStdenv = { buildPackages, baseStdenv }:
              buildPackages.stdenvAdapters.overrideCC baseStdenv buildPackages.llvmPackages_16.clangUseLLVM;
            }
          else import nixpkgs {
            inherit system overlays;
          };


        pkgs = get_pkgs system;

        #with pkgs;
        native_build_inputs =
          let
            git' = pkgs.git.overrideAttrs (old: {
            preInstallCheck =
              pkgs.lib.replaceStrings [ ''disable_test t0201-gettext-fallbacks'' ]
                [ ''
    disable_test t0201-gettext-fallbacks
    disable_test t2082-parallel-checkout-attributes
    '' ]
                old.preInstallCheck;
            });
          in with pkgs; [
          cmake
          ninja
          ccache
          # serene_toolchain.lldb
          # serene_toolchain.lld
          # serene_toolchain.libcxx
          # serene_toolchain.libcxxabi
          # serene_toolchain.compiler-rt
          git'
          zsh
          python3
        ];

         build_inputs = with pkgs; [
          boehmgc
          # llvm_16
          gtest
          gmock
          # zlib-ng
          # zstd
          include-what-you-use
        ];

      in {
          inherit pkgs;
          devShells.default = pkgs.mkShell {
            nativeBuildInputs = native_build_inputs;
            buildInputs = build_inputs;
            shellHook = ''zsh --norcs && exit'';
          };

          packages.cmake = pkgs.cmake;
          packages.blah = pkgs.stdenv.mkDerivation {
            pname = "blah";
            version = "0.1";
            nativeBuildInputs = native_build_inputs;
            buildInputs = build_inputs;
          };
        }
    );
}